субота, 11 жовтня 2014 р.

Рядки

Рядки
1. Рядки (string). Дане типу рядок — це послідовність довільних символів (тобто елементів типу char). Сталі типу рядок записують за допомогою двох штрих-символів, які охоплюють текст. Рядок може містити від 0 до 255 символів. Наприклад, 'Україна', 'Львівська політехніка', '' – порожній рядок нульової довжини, ' ' – рядок, що містить один символ-пропуск.
Змінну типу рядок оголошують за допомогою слова string так:
   var <змінна>: string[n];
де n –довжина рядка, n<256. Довжину рядка можна не зазначати.
Приклад.
            const slovo=’University’;
            var fraza1: string[45]; fraza2: string;
        Над змінними типу рядок визначені операції з’єднання (+) та порівняння (<, <=, >, >=, =, <>). Порівняння двох рядків здійснюється зліва направо до перших різних символів, причому 'A'<'B', 'B'<'C' тощо. “Більшим” вважається символ, який розташований в алфавіті далі. Числовий код символу дає функція ord, наприклад, ord('B')=66, ord('A')=65. Зворотну дію виконує функція chr: chr(66) дає 'B'.
Приклад. Нехай t1='New', t2=' Year'. Тоді з'єднанням цих рядків буде s:=t1+t2 (s матиме значення 'New Year'). Тут s > t1.
Приклад. Вивести на екран малі літери латинського алфавіту та їхні коди можна так: for v:= 'a' to 'z' do writeln(v, ord(v):5).

2. Функції та процедури для дій з рядками. Над даними типу рядок визначені такі стандартні функції:     
length(<рядок>) — визначає кількість символів у рядку;
copy(r, m, n) — дає n символів рядка r, починаючи з символу з номером m;
concat(r1, r2, ..., rn) — з'єднує рядки r1, ..., rn в один рядок;
pos(r1, r2) — визначає номер символу, з якого починається входження
                      рядкаr1 у рядок r2.
та процедури:
insert(r1, <змінна>, n) — вставляє рядок r1 у рядок, заданий змінною,
                                          починаючи з позиції n;
delete(<змінна>, m, n) — вилучає n символів з рядка, заданого змінною,
                                          починаючи з позиції m;
str(<число>, <змінна>) — переводить числове дане в дане типу рядок;
де зазначена змінна посилає в процедуру вхідне дане типу рядок і отримує назад інший рядок – результат виконання процедури.
Приклад. Нехай змінна Lviv має значення 'Львівська політехніка'. Розглянемо приклади функцій та їхні значення:        
Функція                                                    Значення
length(Lviv)                                                   21;
copy(Lviv, 15, 11)                                      техніка;
concat(Lviv,' – 2000')                       Львівська політехніка – 2000;
pos('т', Lviv)                                                           15.
Наступні процедури нададуть змінній Lviv таких значень:  
Процедура                                                          Значення змінної Lviv                    
insert('НУ ', Lviv, 1)                                      'НУ Львівська політехніка'
delete(Lviv, 6, 16)                                                          'Львів'
str(2000, Lviv)                                                                '2000'
val('1256', Lviv1, Ozn)                                        Lviv1=1256, Ozn=0

Є два способи опрацювання даних типу string. Перший — можна опрацьовувати весь рядок як єдине ціле, застосовуючи до нього функції та процедури, другий — можна розглядати рядок як масив, складений з елементів-символів, і опрацьовувати його за правилами роботи з елементами масиву.
Приклад. Деякі значення змінним fraza1 та fraza2 з попереднього прикладу можна надати, а потім вивести тексти на екран так:                                                                        
fraza1:=’Ви любите канікули?’;
for i:=1 to 19 do read(fraza2[i]);{Вводимо текст з клавіатури}
writeln(fraza1); writeln(fraza2).

Задача 1. Кодування інформації. Вилучити з фрази а пропуски, коми і крапки, інші символи продублювати. Вивести результат.                                                            
program MyCode;
uses Crt;
var a, b, c : string; i : integer;
begin
   clrscr;
   write('Введіть текст: ');
   readln(a);                                                            {Вводимо будь-яку фразу}
   b := '';
   for i := 1 to Length(a) do
      begin
      c := Copy(a, i, 1);                                  {Зверніть увагу на коментар унизу:}
      if (c <> ',') and (c <>'.') and (c <>' ' )                      { або так: c := a[i]; }
         then b := b + c + c
      end;
   writeln(b);
   readln
end.                                                                         

Задача 2. Скласти програму, яка скрізь у заданому тексті mytext замінить деяке слово іншим словом такої ж довжини (word1 на word2).                                               
program FindAndChange;
uses Crt;
var mytext, word1,word2 : string; i,k : integer;
begin
   clrscr;
   write('Введіть текст: '); readln(mytext);
   write('Введіть шукане слово: '); readln(word1);
   write('Введіть інше слово: '); readln(word2);
   k := length(word1);
   for i := 1 to length(mytext) - k do
      if copy(mytext, i, k) = word1 then
         begin
         delete(mytext, i, k);
         insert(word2, mytext, i)
         end;
   writeln(mytext);
   readln
end.

Задача 3. Нехай задано рядок 'Я люблю інформатику'. Визначити довжину рядка. Вивести на екран друге слово цього рядка.                                                                    
program Ryadok;
uses Crt;
const r1: string = 'Я люблю інформатику';
var i,k,m,n1,n2: integer;
begin
   clrscr;
   m:=0;
   k:=length(r1);                                                 {Визначаємо довжину рядка}
   writeln('Довжина рядка k=', k);
   for i:=1 to k do                                               {Переглядаємо всі символи рядка}
      if r1[i]=' ' then                                                       {Шукаємо пропуск}
         begin
         m:=m+1;
         if m=1 then n1:=i;        {Визначаємо номер першого та другого пропусків}
         if m=2 then n2:=i
         end;
   for i:=n1+1 to n2–1 do write(r1[i]);    {Виводимо слово між двома пропусками}
   readln
end.                                                                         


Масиви

Масиви
Масив (array) — це скінчений набір елементів одного (базового) типу, які зберігаються в послідовно розташованих комірках оперативної пам’яті і мають спільну назву.
У математиці поняттю мaсив відповідають поняття вектора та матриці. Розрізняють одно (рядки, стрічки, вектори)- та багатовимірні масиви. Двовимірний масив даних — це таблиця, що складається з декількох рядків.

1. Одновимірні масиви (рядки, вектори):
Загальний вигляд конструкції опису типу масиву такий:
      TYPE   
<назва типу>=array [<розмір>] of <назва базового типу>;
можна і так:
     <список змінних>:array [<розмір>] of <назва базового типу>;
Розмір (кількість елементів) масиву найчастіше задають у вигляді діапазону або назви деякого перерахованого типу даних.
Описати масив можна у розділі опису типів type, у розділі констант const, або у розділі оголошення змінних var. Назви типів масивів і змінних-масивів придумує користувач.
Приклад. Розгляньте: 1) опис типу масивів (назва типу mymasyv), 2) оголошення cталого масиву (масиву-константи) vydatky типу mymasyv і 3) оголошення змінних-масивів a, a1 типу mymasyv та масивів: b (він має 7 елементів цілого типу), c (має 100 елементів-символів, тобто даних типу char).  
type mymasyv= array [1..10] of real;
      day=(mon, tue, wed, the, fri, sat, sun);
const vydatky: mymasyv =(1.2, 1, 1, 2, 18, 2.4, 8.97, 3, 7, 1.3);
var a, a1: mymasyv;
      b: array[day] of integer;
      c: array [1..100] of char;
Над масивами визначена єдина команда копіювання: a:=a1 – усі значення масиву a1 будуть присвоєні відповідним еле­ментам масиву a. Усі інші операції, наприклад, присвоєння конкретних значень, додавання, множення тощо, визначені лише над елементами масиву.
Доступ до елемента масиву здійснюється через назву масиву і номер елемента. Цей номер (його часто називають індексом) записується в квадратних дужках, наприклад, a[1] - перший елемент масиву а, b[tue]-другий елемент масиву b.
Щоб опрацювати всі елементи масиву використовують команду циклу for (чи while або repeat).
Приклад.Елементам описаних масивів можна надати значення так: a[1]:=15.1; b[tue]:=3; с[1]:=’a’; c[2]:=’b’. Сталі елементи мають такі значення: vydatky[1]=1.2; vydatky[2]=1; …; vydatky[10]=1.3.
Приклад. Створити масив з перших ста цілих чисел і обчислити суму всіх його елементів можна так: s:=0; for i:=1 to 100 do begin a[i]:=i; s:=s+a[i] end; writeln(s);
Задачі відшукуання в масиві конкретних даних розв’язують методом сканування (перебирання, перегляду) усіх елементів масиву за допомогою циклу і умовної команди, де зазначають умову пошуку.
Задача 1. Нехай yk — це число викликів, які поступають на АТС за k-ту секундy. Припустимо, що yk — випадкове число зі значенням від 0 до 6, яке генерується формулою yk=trunc(abs(7sin(k))). Утворити масив y з десятьма елементами . Обчислити суму викликів за перші 10 секунд роботи АТС та максимальну кількість викликів, що були за деяку одну секунду. Вивести результати обчислень.                                                           
program ATS;
uses Crt;
type vyklyk= array[1..10] of integer;
var y: vyklyk; max, s, i: integer;
begin
   clrscr;
   max:=0; s:=0;                                          {Припустимо, що max=0}
   for i:=1 to 10 do
      begin
      y[i]:=trunc(abs(7*sin(i)));                               {Обчислимо кількість викликів}
      write('Кількість викликів за ', i, '–ту секунду: ');          {за і-ту секунду}
      writeln(y[i]:5);                                                         {Виведемо цю кількість}
      s:=s+y[i];                                                            {Обчислимо суму викликів}
      if y[i]>max then max:=y[i];                               {Обчислимо max значення }
      end;
   writeln('Кількість викликів за 10 секунд = ', s:3);
   write('Максимальна кількість викликів за одну ');
   writeln('секунду = ', max:3);
   readln
end.                                                                         
Зауваження. Випадкове ціле число зі значенням від 0 до 6 можна згенерувати також за допомогою функції random(7). На початку виконуваного блоку слід записати виклик процедури randomize (вона забезпечить іншу послідовність випадкових чисел під час виконання програми вдруге).
Задача 2. Утворити масив y, елементи якого обчислюються за формулою yk=ln(k)–3, де  . Побудувати масив g, який складається з від'ємних елементів масиву y. Вивести результати обчислень. Якщо шуканих величин немає, вивести про це повідомлення.
У наступній програмі змінна n визначає кількість від’ємних елементів у новому масиві.          
program DvaMasyvy;
uses Crt;
var y,g: array [1..10] of real;
      k,n: integer;
begin clrscr;
   n:=0;                                                 {Спочатку кількість елементів у g = 0}
   for k:=1 to 10 do
   begin
      y[k]:=ln(k)–3;
      if y[k]<0 then                                    {Перевіримо чи елемент від'ємний}
         begin
         n:=n+1;                                    {Збільшимо кількість елементів вектора g}
         g[n]:= y[k];                                   {Знайдемо n-ий елемент}
         end;
      writeln('y(' , k, ')=' , y[k]:7:2);
      end;
   if n=0 then writeln('Масив у від''ємних елементів не має')
   else
      for k:=1 to n do
         writeln('g[' , k , ']=' , g[k]:7:2);                   {Виведемо масив g }
   readln
end.                                                                         

2. Двовимірні масиви (матриці). Елементи двовимірного масиву (дані можуть бути подані у вигляді таблиці-матриці) визначаються іменем масиву та двома індексами: перший індекс означає номер рядка, а другий — номер стовпця, на перетині яких стоїть елемент, наприклад р[1,2], p[i,j].
Загальний вигляд конструкції опису типу матриці такий:
      TYPE   
<назва типу>=array [<розмір>, <розмір>] of <назва базового типу>;
можна і так:
     <список змінних>:array [<розмір>,<розмір>] of <назва базового типу>;
Розглянемо приклади оголошення масиву-константи bal, що має 2 рядки і 4 стовпці елементів, деякого масиву doba, який міститиме 24·60 елементів цілого типу, двовимірного масиву р розміру 9 на 9 (тут буде 9·9=81 елемент).     
const bal: array [1..2, 1..4] of integer=((4,3,5,3), (4,4,5,3));
var doba: array [0..23] of array [0..59] of integer;
const n = 9;
var p : array [1..n, 1..n] of integer;

Тут bal[1,1]=4, bal[1,2]=3, …, bal[2,3]=5, bal[2,4]=3. Значення елементам масивів doba i p можна надати командою присвоєння двома способами,наприклад, так: doba[16][30]:=5, doba[16,30]:=5.

Задача 3. Скласти програму для занесення в двовимірний масив р таблиці множення двох чисел і виведення масиву на екран.                                                                    
program Pifagor;
uses Crt;
const n = 9;
var p: array [1..n, 1..n] of integer;   i, j : integer;
begin    clrscr;
   for i := 1 to n do  begin
      for j := 1 to n do  begin
         p[i, j] := i * j;
         write(p[i, j] : 6)                   {Зверніть увагу на команди виведення масиву}
         end;                                       {у вигляді таблиці}
      writeln
      end;
   readln;    end.                                                     
Задача 4. Кондитерська фабрика для виготовлення п'яти сортів цукерок використовує п'ять видів сировини. Нехай норми затрат aij кожного виду сировини і на виробництво 1т цукерок сорту j задані формулою aij = 2|Sin(i)|+j, . Вивести на екран таблицю затрат сировини (тобто масив а). Визначити для якого сорту цукерок (imin) потрібно найменше сировини (min) третього виду.                                                                      
program Fabryka;
uses Crt;
type vytraty = array [1..5, 1..5] of real;
var i,j,imin: integer; min: real;   a:vytraty;
begin    clrscr;
   writeln(' Вид сировини');
   writeln(' 1 2 3 4 5');
   for i:=1 to 5 do                                               {Утворимо таблицю затрат}
      begin
      write(i, ' сорт');                                        
      for j:=1 to 5 do
         begin
         a[i,j]:=2*abs(sin(i)) +j;
         write(a[i,j]:7:2);                                     {Роздрукуємо елементи і-го рядка}
         end;
      writeln                                                     {Перейдемо на новий рядок}
      end;
   imin:=1;
   min:=a[1;3];                           {Припустимо, що найменше сировини третього}
   for i:=2 to 5 do                       {виду потрібно для цукерок першого сорту}
      if a[i,3]<min then
         begin
         min:=a[i,3]; imin:=i;                           {Визначимо шуканий сорт цукерок}
         end;
   writeln('Найменше сировини третього виду ');
   writeln('потрібно для цукерок ', imin, ' сорту');
   readln;  end.                                                       

Зауваження. Нехай задана деяка матриця ai,j, . Тоді вирази i = j, i < j та i > j визначають відповідно елементи головної діагоналі, елементи над та під головною діагоналлю цієї матриці. 

Практична робота

1.      Робота проводиться в програмній оболонці Turbo Pascal.
2.      Для перемикання розкладки клавіатури використовується комбінація правих та лівих Ctrl+Shift.
3.      Для компіляції використовується меню Сompile пункт Make або клавіша F9.
4.      Для запуску на виконання використовується меню Run пункт Run або комбінація Ctrl+F9.
5.      Для перегляду вікна роботи програми  використовувати комбінацію клавіш Alt+F5.
6.      Ввод даних в програму проводиться за допомогою клавіші Enter.
7.      Зупинка виконання програми до її закінчення реалізовується подвійним натискуванням комбінації клавіш Ctrl+Break.
8.      Масивом називається скінчений набір даних одного типу, пронумерований в певному порядку.
9.      Масиви визначаються у програмі за допомогою структури                                                  array [<розмірність>] of <тип>.
10.  Одномірний масив (лінійний) являє собою ланцюжок даних, довжина якого обмежена довжиною самого масива.
11.  Кожен елемент лінійного масива має один індекс або порядковий номер.
12.  До введення даних в масиві можуть знаходитись будь-які значення.
13.  Введення,  виведення і обробка всіх елементів масиву проводиться у циклі.

Завдання 1.
Розв'язати нижче вміщені задачі, написати програму на мові Pascal, скомпілювати її та, запустивши, отримати результати. Результати виконання, тестові приклади та тексти програм записати до зошита з практичних робіт.
  1. Створити  цілочисельний  одномірний  масив А[1..n]  (n=5)    з   елементами, рівними своїм подвоєним індексам  та вивести його на екран.
  2. Знайти кількість від`ємних, додатніх та нульових елементів  в   лінійному цілочисельному масиві.
  3. Знайти номер першого від`ємного елемента  в  лінійнійному  масиві дійсних чисел.
  4. Знайти середнє арифметичне  всіх  додатніх елементів лінійного  масиву дійсних чисел.

Додаткове завдання:
1. Вивести на екран всі від`ємні елементи лінійного цілого масива.
2. Знайти всі прості  числа  в  лінійному  цілочисельному  масиві довжиною N та вивести їх на екран.


Зауваження для вчителя: задачі, починаючи з другої, розв’язувати на основі раніше створених.

Домашнє завдання:
  1. Підготуватись до практичної роботи № 35. Тема “Двомірні масиви.” .
1.2   Переписати до зошита з практичних робіт інструкцію до роботи № 35.
1.3  Повторити опис та введення двомірних масивів в Pascal.
1.4  Повторити основні правила роботи з двомірними масивами у Pascal.

Запитання до захисту практичної роботи:
1.      Що таке масив?
2.      Які масиви бувають?
3.      Що таке індекс елемента масиву?
4.      Скільки індексів у елемента лінійного масиву?
5.      Яким чином проводиться введення і виведення всіх елементів масиву?